.include "cydheader.a64"
		

         *= game3

player   = game2
bomb     = game2+3
gspace   = game2+6
;
stopshot = game2+12
sshot    = game2+15
sbox     = game2+18
cshot    = game2+21
scroll   = game2+24
in18     = game2+27
gplayr   = game2+30
setscrn  = game2+33
plres1   = game2+36
gppos    = game2+39
loscr    = game2+42
hiscr    = game2+42+28

chsex    = blok+$0900



fx       = sound+6

spdzei   = $d2
bkgrp    = map-$0100
;submem   = tool

;---------------------------------------

         jmp subjmain
         jmp ssubstat
         jmp prodsub
         jmp plrcoll
         jmp subjinit
         jmp shotcoll
         jmp killsub
         jmp initwam
         jmp metam
         jmp cdown
         jmp cright
         jmp cleft
         jmp rsallsb


aam      .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
wam      .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
init     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
awamz    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
aaamz    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
produc   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
parea    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
cwri     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
cwle     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
cwdo     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
cwup     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
subsn    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
							;--- modified ---	added
								;provisorisch, durch bug wird hier
								;von oben reingeschrieben
         .byte 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0


;-----------------------------------


cleft
         .block
         lda $da
         asl a
         adc $da
         adc $d9
         adc #>blok
         sta $d5

         lda icox1
         sta $d7

         jsr nwal2
         inc cwle,x
         rts
         .bend

nwal2
         lda conty,x
         sta $db

         ldx icoy1
         lda icoy3
         and #4
         bne cn6
         sec
         lda $d5
         sbc #3
         cmp #>blok
         bcs cn7
         dex
         adc #6
cn7      sta $d5
cn6      stx $d8

         ldy #0
nwal
         lda ($d7),y
         sta $d4
         lda ($d4),y
         tax
         lda chsex,x
         beq wallx
         lda $d5
         cmp #>blok+$0300
         bcs cn1
         adc #3
         dec $d8
         bne cn2
cn1
         sbc #3
cn2      sta $d5
         dec $db
         bne nwal
         pla
         pla
         jmp freex
     ;   .bend

wallx
         .block
         clc
         ldx $d6
         lda awlox,x
         beq n3
         bmi n1
         lda #8
         sbc cox3,x
         tay
         lda #7
         bne n2
n1
         lda cox3,x
         eor #$ff
         adc #1
         tay
         lda #0
n2       sta cox3,x
         sta icox3
         lda cox2,x
         sta $d9
         lda cox1,x
         sta icox1
         tya
         sta awlox,x
      ;  bne n3
      ;  lda #0
      ;  sta awhix,x
n3       rts
         .bend

cright
         .block
         clc
         lda $d9
         adc contx,x
         tay
         lda tablx-1,y
         adc $da
         adc $da
         adc $da
         adc #>blok
         sta $d5
         lda tabbx-1,y
         adc icox1
         sta $d7

         jsr nwal2
         inc cwri,x
         rts


tablx    .byte 1,2,0,1,2,0,1,2,0,1,2,0
         .byte 1
tabbx    .byte 0,0,1,1,1,2,2,2,3,3,3,4
         .byte 4
         .bend


freex
         ldx $d6
         lda icox1
         sta cox1,x
         lda $d9
         sta cox2,x
         lda icox3
         sta cox3,x
         rts
freey
         ldx $d6
         lda icoy1
         sta coy1,x
         lda $da
         sta coy2,x
         lda icoy3
         sta coy3,x
         rts

cup
         .block
         sec
         lda $da
         sbc conty,x
         sta $d7
         and #1
         sta $d4
         asl a
         adc $d4
         adc $d9
         adc #>blok
         sta $d5

         lda #0
         ldy $d7
         bpl n1
         tya
         lsr a
         ora #$80
n1       clc
         adc icoy1
         sta $d8
         lda icox1
         sta $d7

         lda contx,x
         sta $db

         jsr nflo2
         inc cwup,x
         rts
         .bend

cdown
         lda $da
         asl a
         adc $da
         adc $d9
         adc #>blok
         sta $d5

         lda icox1
         sta $d7
         lda icoy1
         sta $d8

         lda contx,x
         sta $db

         jsr nflo2
         inc cwdo,x
         rts

cyadapt1 .byte >blok+$0100,>blok+$0200
         .byte >blok+$00
         .byte >blok+$0400,>blok+$0500
         .byte >blok+$0300
cyadapt2 .byte $ff,$ff,0,$ff,$ff,0

nflo2
         lda icox3
         and #4
         jmp cn10
         sec
         lda $d5
         sbc #>blok
         tax
         lda cyadapt1,x
         sta $d5
         lda cyadapt2,x   ;carry htb set
         adc $d7
         sta $d7
cn10
         ldy #0
nflo
         lda ($d7),y
         sta $d4
         lda ($d4),y
         tax
         lda chsex,x
         beq wally
         ldx $d5
         inx
         cpx #>blok+$0600
         bcs dn2
         cpx #>blok+$0300
         bne dn1
         ldx #>blok
         bne dn3
dn2
         ldx #>blok+$0300
dn3      inc $d7
dn1
         stx $d5
         dec $db
         bne nflo
         pla
         pla
         jmp freey


wally
         .block
         clc
         ldx $d6
         lda awy,x
         beq n3
         bmi n1
         lda #8
         sbc coy3,x
         sta awy,x
         lda #7
         sta coy3,x
         rts
n1
         lda coy3,x
         eor #$ff
         adc #1
         sta awy,x
         lda #0
         sta coy3,x
n3       rts
         .bend


originalsubjmov = 1		; 1 = original-version

subjmain
         .block

	.ifeq originalsubjmov
	lda $df
	beq eend
	.endif

	.if originalsubjmov
         lda $df
         cmp subfreq
         bne eend
	.endif

         ldx status
         bmi n1
n2
         #rcol3 "01"
         jsr incsubj
         #rcol3 "00"
n1
	.ifeq originalsubjmov
	lda #0
	sta $df
	.endif

	.if originalsubjmov
         inc subfreq
	.endif
         jmp movesu
         .bend


ssubstat
         stx status
eend     rts

movf     .byte 0


stimupversion	= 1		; 1 = ursprüngliche smonst4-version

	.ifeq stimupversion
stimup
         .block
         #rcol2 "00"
         lda movf
         bne n1

n3       lda sumod,x
         bne n2
         inc awphast,x
     ;   inc aphast,x
n2       dex
         bpl n3
         ldx #zz-4
n1
         lda sumod,x
         beq n4
         inc awphast,x
      ;  inc aphast,x
n4       dex
         bpl n1
         .bend
	.endif

	.if stimupversion
stimup
         pla
         pla
         rts
       ; .bend
	.endif

movesu
         lda #0
         sta movf
         jsr movsu3
         inc movf
         jsr movsu3
         rts

movsu3
         ldx #zz-4
movsu2
	.if originalsubjmov
         lda $df
         cmp subfreq
         beq stimup
	.endif

         ldy subj,x
         beq nn2

         lda sumod,x
         bne nn3
         lda movf
         beq nn4
         bne nn2
nn3
         asl a           ;bit7 retten
         lda movf
         beq nn2
         bcc nn4
                    ;mod vorerst erhoeht
         lda #1
         sta sumod,x
         bpl nn2

nn4
         #rcol3 "05"
         stx $d6
         lda submem,y
         sta nn0+1
         lda submem+1,y
         sta nn0+2
         lda aamlob,x
         sta $d2
         lda aamhib,x
         sta $d3
nn0      jsr submem
         #rcol "07"
         jsr waysu
         #rcol "04"
         jsr showsu
         #rcol3 "00"
nextsu   ldx $d6
nn2
         dex
         bpl movsu2
         rts

showsu
         .block
         ldx $d6
         lda sumod,x
         beq n1
         jmp inarea
n1
         jsr subarea
         jmp setsu
         .bend

shotcoll
         .block
         clc
         lda $36
         bmi n1
         lda $dc
;         sta $1058		;--- modified --- (wohl zum debuggen)
         sta $d4
         lda $dd
;         sta $1059
         sta $d5
         lda $de
;         sta $105a
         sta $d7
         adc #8
;         sta $105b
         sta $d8
         ldx $d6
         jsr coll
         bcc n1
         jmp stopshot
n1       rts
         .bend

coll
         .block
         txa
         asl a
         asl a
         tax
         ldy subsn,x
         ldx $d6
         lda shix,y
         lsr a
         lda slox,y
         ror a

;         sta $1050		;--- modified --- (wohl zum debuggen)

         cmp $d5
         bcs n1
         adc collxd,x

;         sta $1051

         cmp $d4
         bcc n5
         clc
         lda sy,y
         adc colbasy,x

;         sta $1052

         cmp $d8
         bcs n1
         adc collyd,x

;         sta $1053

         cmp $d7
n5       rts
n1       clc
         rts
allr     .byte 0
         .bend

plrcoll
         .block
         clc
       ; rts

         lda $14
         adc #6
         sta $d7
         adc #21-6-6
         sta $d8
         lda #$b0/2
         sta $d4
         lda #$b8/2
         sta $d5
         jmp coll
         .bend

initwam
         lda #0
         sta awamz,x
         lda #1
         sta awphast,x
         rts

waysu
         .block
         ldx $d6
         ldy unsharp,x
         iny
         tya
         and #1
         sta unsharp,x
         bne s1

         lda wam,x
         cmp oldwam,x
         beq n1c
         lda #1
         sta aphast,x
         bne n1b
n1c
         dec awphast,x
         bne n1
n1b
         #rcol3 "01"
         jsr interpr
         #rcol3 "07"
         ldx $d6
n1
         lda awy3,x
         sta awy,x
         lda awlox3,x
         sta awlox,x

         lda wam,x
         sta oldwam,x
s1

         lda #0
         sta cwri,x
         sta cwle,x
         sta cwdo,x
         sta cwup,x

         lda coy3,x
         sta icoy3
         lda coy1,x
         sta icoy1
         lda coy2,x
         sta $da

         lda cox3,x
         sta icox3
         lda cox1,x
         sta icox1
         ldy cox2,x
         sty $d9


         clc
         lda awlox,x       ;awlox
         sta wx+1
         beq n40
         adc cox3,x
         bpl n20
         dey
         jmp n21b
n20      cmp #8
         bcc n21
         iny
n21b     and #7
         sta icox3
         tya
         bpl n22
         clc
         adc #3
         dec icox1
         jmp n23
n22      cmp #3
         bcc n23
         sbc #3
         inc icox1
n23      sta $d9
         jmp n40

n21      sta icox3
         lda #0
         sta wx+1
         sty $d9
n40
wx       lda #0
         beq n35
         bmi n24
         jsr cright
         jmp n100
n24      jsr cleft
         jmp n100
n35      jsr freex

n100
         ldx $d6
         lda coy1,x
         sta icoy1
         ldy coy2,x
         sty $da


         lda awy,x       ;awy
         sta wy+1
         beq n52
         clc
         adc icoy3
         bpl n30
         dey
         jmp n31b
n30      cmp #8
         bcc n31
         iny
n31b     and #7
         sta icoy3
         tya
         bpl n32
         dec icoy1
         jmp n33
n32      cmp #2
         bcc n33b
         inc icoy1
n33      and #1
n33b     sta $da
         jmp n52

n31      sta icoy3
         lda #0
         sta wy+1
         sty $da

n52
wy       lda #0
         beq n53
         bmi n34
         jmp cdown
n34      jmp cup
n53      jmp freey

n50      rts

interpr
         clc
         lda wam,x
         adc wamtz,x
         jsr tgetr
         ldy awamz,x
n7       lda ($d0),y
         bpl n2
         sta konst+1
         bit konst
         bne n10
         and #$0f       ;+
         jmp n11
n10
         and #$0f       ;-
         eor #$ff
         clc
         adc #1
n11
         bit konst+1
         bvs n12
         sta awlox3,x
      ;  sta awlox2,x
         jmp n13
n12
         sta awy3,x
       ; sta awy2,x
n13
         lda konst+1
         and #$20
         beq n14
      ;  sec
         lda wphast,x
      ;  sbc #1
         sta awphast,x
         iny
         tya
         sta awamz,x
         rts
n2
         beq n6
         cmp #$70
         bcs n9
         sta wphast,x
n14      iny
         jmp n7
n6
         lda #0
         sta awamz,x
         tay
         jmp n7
n9
         and #$0f
         sta aam,x
      ;  lda #0
      ;  sta awamz,x
         iny
         jmp n7

konst    .byte $10,0
         .bend


tgetr
         asl a
         tay
         lda ($d2),y
         sta $d0
         iny
         lda ($d2),y
         sta $d1
         rts

setsu
      ;  #rcol3 "03"
      ;  jsr setsu2
      ;  #rcol3 "04"
      ;  rts

;setsu2
         .block
         ldx $d6

         lda unsharp,x
         beq s1

         dec aphast,x
         bne n21
         jsr interpr
         ldx $d6
n21
s1
         lda sumod,x
         beq nend
         rts
nend
         lda spanz,x
         sta gallr
         txa
         asl a
         asl a
         tax
         ldy subsn,x
         ldx $d6
      ;  lda awlox,x
      ;  cmp #$80        ;war inarea?
      ;  bne n60
      ;  lda awlox3,x
      ;  sta awlox,x
      ;  lda slox,y
      ;  sta n30+1
      ;  lda shix,y
      ;  sta n31+1
      ;  lda sy,y
      ;  jmp n61
n60
       ; clc             ;carry htb clr
         lda awlox,x
         bmi n70
         adc slox,y
         sta slox,y
         sta n30+1
         lda shix,y
         adc #0
         jmp n71
n70
         adc slox,y
         sta slox,y
         sta n30+1
         lda shix,y
         adc #$ff
n71
         sta shix,y
         sta n31+1
         clc
         lda sy,y
         adc awy,x
         sta sy,y
n61      sta n32+1

         txa
         asl a
         asl a
         tax
         lda sdz3,x
         sta sdz,y
         lda scol3,x
         sta scol,y

n34      inx
         dec gallr
         beq end
         ldy subsn,x
         clc
         lda sdelx,y
n30      adc #0
         sta slox,y
         lda #0
n31      adc #0
         sta shix,y
         clc
         lda sdely,y
n32      adc #0
         sta sy,y
         lda sdz3,x
         sta sdz,y
         lda scol3,x
         sta scol,y
         jmp n34
end      rts

interpr
         lda aam,x
         jsr tgetr
         ldy aaamz,x
n37
         ldx $d6
         lda spanz,x
         sta gallr
n16b     lda ($d0),y
         beq loop
         cmp #$10
         bcc n1
         cmp #$30
         bcc n2
         bcs n4

loop     lda #0
         sta aaamz,x
         tay
         jmp n16b
n4
         txa
         asl a
         asl a
         tax
n11      lda ($d0),y
         sta sdz3,x
         inx
         iny
         dec gallr
         bne n11

         ldx $d6
         tya
         sta aaamz,x
      ;  sec
         lda phast,x
      ;  sbc #1
         sta aphast,x
         rts
n1
         sta phast,x
         iny
         jmp n16b
n2
         txa
         asl a
         asl a
         tax
n12      lda ($d0),y
         cmp #$20
         bcc n13
         eor #$80
n13
         sta scol3,x
         inx
         iny
         dec gallr
         bne n12
         jmp n37
         .bend


incsubj
         .block
         lda $ab
         sta $d1
         cmp #>map
         bcs n20
         lda #>map
n20      sta $d5
         lda #$ff
         sta status

         lda tab1,x
         lsr a
         sta $d3
         ldx $a8
         bcc n5
         lda $a8
         cpx #2
         bne n5
         ldy #$fd           ;-3 map-pos
         jsr spalte
n5       lsr $d3
         bcc n6
         cpx #1
         bne n6
         ldy #13
         jsr spalte
n6       ldx $a9
         lsr $d3
         bcc n7

         lda $d1
         jsr reihe
n7       lsr $d3
         bcc n8
         lda $d1
         adc #7
         cmp #>map+$2000
         bcs n8
         sta $d1
reihe
         cmp #>map
         bcc n8
         ldy #0
         lda #12
         adc $aa
         sta $d0
n0       lda ($d0),y
         lsr a
         tax
         lda bkgrp,x
         beq n10
         jsr setnsub
n10      dec $d0
         lda $d0
         cmp $aa
         bne n0
n8
         rts
spalte

         clc
         lda $d1
         adc #9+5
         cmp #>map+$2100  ;map unten?
         bcc n30
         lda #>map+$2000
         clc
n30      sta $d1

         tya
         adc $aa
         sta $d0
         ldy #0
n1
         dec $d1
         lda $d1
         cmp $d5
         bcc n8
         lda ($d0),y
         lsr a
         tax
         lda bkgrp,x
         beq n1
         jsr setnsub
         jmp n1

tab1     .byte $02,$01,$08,$0a
         .byte $09,$04,$06,$05
         .byte $00,$02,$01
         .bend

gallr    .byte 0
setnsub
         .block
         sta gallr
         lda ($d0),y
         lsr a
         bcs n1

         lda gallr
         ldy #0
         jsr getsubj
         bmi n1

         stx $d6
         lda $d0
         sta blockx,x
         sta cox1,x
         lda $d1
         sta blocky,x
         sta coy1,x
         lda #0
         sta cox2,x
         sta cox3,x
         lda #1
         sta coy2,x
         lda #7
         sta coy3,x

         jsr cotos

         ldy #0
         lda ($d0),y
         ora #1
         sta ($d0),y
n1       ldy #0
         rts
         .bend

metam
         jsr iprod
         jsr decsubj
         lda $db
         ldy smod
         jsr getsubj2
         jsr prods
         pla
         pla
         jmp movsu2

iprod
         sta $db
         lda #0
         stx $d7
         ldx $d7
         bpl nn10
         lda #$ff
nn10     sta $da
         sty $d8
         ldx $d6
         lda cox1,x
         sta icox1
         lda cox2,x
         sta icox2
         lda cox3,x
         sta icox3
         lda coy1,x
         sta icoy1
         lda coy2,x
         sta icoy2
         lda coy3,x
         sta icoy3
         lda sumod,x
         sta smod
         bne retn1
         txa
         asl a
         asl a
         tay
         ldx subsn,y
         lda slox,x
         sta osu1+1
         lda shix,x
         sta osu2+1
         lda sy,x
         sta osu3+1
retn1    rts

smod     .byte 0

prodsub
       ; rts
         jsr iprod
         lda $db
         ldy smod
         jsr getsubj
         bmi retn1
prods    stx $d9
         lda #0
         sta blocky,x
         lda $d6
         sta produc,x
         lda smod
         bne end7
         txa
         asl a
         asl a
         tay
         ldx subsn,y
         clc
osu1     lda #0
         adc $d7
         sta slox,x
osu2     lda #0
         adc $da
         sta shix,x
         clc
osu3     lda #0
         adc $d8
         sta sy,x

end7     jmp stoco


getsubj2
         sty smod2+1
         sta allr2+1
         jmp gets3
getsubj
         .block
         sty smod2+1
         sta allr2+1

      ;  ldy freobz
      ;  ldx freobsk,y

         ldx #zz-4    ;hell 9!
m1       lda subj,x
         beq gets2
         dex
         bpl m1
         tya
         beq koldsu
         lda #$ff
end      rts
koldsu
       ; ldy #zz-4
       ; ldx ksuz
       ; dex
       ; bpl n1
n3       ldx #zz-4
n1
         lda sumod,x
         bne n2
   ;     dey
   ;     bmi end
         dex
         bpl n1
         bmi end     ;n3
n2
         stx ksuz
         jsr subblk2


u        = 1
         .ifeq u
         ldx smod2+1
         beq n2b
         lda #$ff
         rts
;n2b
         sta n3+1
         ldx #zz-4
;n2       lda sumod,x
         bne n1
         dex
         bpl n2
         rts
;n1
         lda $d6
         pha
         stx $d6
         jsr subblok
         ldx $d6
         pla
         sta $d6
;n3       lda #0
         jmp getsubj2
         .endif
         .bend


       ; dec freobz
gets2
         lda allr2+1
gets3    asl a
         asl a
         asl a
         sec
allr2    sbc #0
         sta subj,x
         sta $d4
smod2    lda #0
         sta sumod,x
         lda #>submem
         sta $d5
         ldy #2
         lda ($d4),y
         sta aamlob,x
         iny
         lda ($d4),y
         sta aamhib,x
         iny
         lda ($d4),y
         sta wamtz,x

         iny
         lda ($d4),y
         and #$0f
         sta contx,x
         asl a
         asl a
         sta collxd,x
         lda ($d4),y
         lsr a
         sta collyd,x
         lsr a
         lsr a
         lsr a
         sta conty,x
         tay
         lda ctbasy,y
         sta colbasy,x

         ldy #6
         lda ($d4),y
         sta konstl,x
         tay
         lda kontab,y
         sta spanz,x

         lda #0
         sta aaamz,x
         sta awamz,x
         sta init,x
       ; lda $df
       ; clc
         lda #1
         sta aphast,x
         sta awphast,x

         lda sumod,x
         beq getsprit
         rts

getsprit
         .block
       ; #rcol3 "07"
         stx allr+1
         lda konstl,x
         sta konstel
         lda spanz,x
         sta allr

         lda #$ff
         sta konsz
         ldy spritz
         txa
         asl a
         asl a
         tax
n1       lda sy,y
         beq n5
         dey
         bpl n1
         ldx allr+1
         lda #0
         sta subj,x
       ; #rcol3 "00"
         lda #$ff
         rts

n5
         tya
         sta subsn,x

         lda konsz
         bmi n10
         stx allr3+1
         lda konstel
         asl a
         adc konstel
         adc konsz
         tax
         lda konxd,x
         sta sdelx,y
         lda konyd,x
         sta sdely,y
allr3    ldx #0
n10
         inc konsz
         dey
         inx
         dec allr
         bne n1
         sty spritz
         ldx allr+1
      ;  #rcol3 "00"
         rts
allr     .byte 0,0
konstel  .byte 0
konsz    .byte 0
         .bend

putsprit
         .block
         ldx $d6
         lda sumod,x
         bne end

         lda #zz-4
         sta spritz
         lda spanz,x
         sta gallr
         txa
         asl a
         asl a
         tax
n1    ;  inc stackz
         ldy subsn,x
         lda #0
         sta sy,y
      ;  tya
      ;  ldy stackz
      ;  sta sstack,y
         inx
         dec gallr
         bne n1
end      rts
         .bend

spritz   .byte 0
;stackz   .byte 10
;sstack   .byte $ff,0,1,2,3,4,5,6,7,8,9

;freobz   .byte 10
;freobsk  .byte $ff,0,1,2,3,4,5,6,7,8,9

inarea
         .block
         sec
         lda cox1,x
         sbc $aa
         cmp #$fd
         bcs n2
         cmp #14
         bcs n1
         sec
n2       lda coy1,x
         sbc $ab
       ; beq n1
         cmp #9+3 - 2  ;--- modified ---
         bcs n1
         jsr getsprit
         bmi decsubj2
         dec sumod,x

     ;   lda awlox,x
     ;   sta awlox3,x
      ;  lda #$80
      ;  sta awlox,x

         jmp cotos

n1       rts
         .bend

subarea
         .block
         ldx $d6
         sec
         lda cox1,x
         sbc $aa
         cmp #$fd
         bcs n2
         cmp #14
         bcs decsu
         sec
n2       lda coy1,x
         sbc $ab
       ; beq n1
         cmp #9+3 - 2  ;--- modified ---
         bcs decsu

      ;  ldx $d6
      ;  lda subj,x
      ;  beq n10
      ;  txa
      ;  asl a
      ;  asl a
      ;  tax
      ;  ldy subsn,x
      ;  lda sy,y
      ;  cmp #$18
      ;  bcc decsu
      ;  cmp #$a4+$38
      ;  bcs decsu
      ;  lda shix,y
      ;  lsr a
      ;  lda slox,y
      ;  bcc n10      ;n1
      ;  cmp #$b0
      ;  bcs n10
      ;  cmp #$50
      ;  bcs decsu
n1       rts

decsu
         jsr putsprit
         ldx $d6
         lda #$80
         sta sumod,x
         rts
         .bend

killsub
         jsr decsubj
         jmp nextsu


decsubj2
         jsr subblok
decsubj
         jsr putsprit
         ldx $d6
;decsubj3 inc freobz
        ;ldy freobz
        ;txa
        ;sta freobsk,y
         lda #0
         sta subj,x
         rts

subblok
         ldx $d6
subblk2
         .block
         lda blocky,x
         beq n2
         sta n1+2
         lda blockx,x
         sta n1+1
n1       dec map
n2       rts
         .bend
rsallsb
         .block
         ldx #zz-4
n2       lda subj,x
         beq n1
         jsr subblk2
n1       dex
         bpl n2
         rts
         .bend

subjinit
         .block

	.ifeq originalsubjmov
	lda #0
	sta $df
	.endif

	.if originalsubjmov
         clc
         lda $df
         adc #strange_df_subfreq	;--- modified ---
				;#2 ist original
				;wenn man etwa #10 addiert, erscheinen
				;die gegner sofort schnell am anfang

         sta subfreq
	.endif

         ldx #zz-4+1
         stx ksuz

         ldx #zz-4
         stx spritz
n1       lda #0
         sta subj,x
       ; txa
         dex
         bpl n1

         ldx #(zz*5)-1  -3	;-- modified --    added "-3" : loesche nicht spielerspritesfarben
         lda #0
n3       sta sdat,x
         dex
         bpl n3
         rts
         .bend

cotos                  ;subj-cord to
         .block        ;sprite-cord
         ldx $d6
                       ;X-CORD
         sec           ;deltablock
         lda cox1,x
         sbc $aa
         sta $d7
         lda #0
         sbc #0
         sta $d9
         sta $d8

         lda $d7       ;mal 3
         asl a
         rol $d8
         clc
         adc $d7
         sta $d7
         lda $d8
         adc $d9
         sta $d8

         sec           ;sbc blk-char-zei
         lda $d7
         sbc $a8
         bcs n1
         dec $d8
n1
         clc           ;add cox2
         adc cox2,x
         bcc n2
         inc $d8
n2
         asl a         ;mal 8
         rol $d8
         asl a
         rol $d8
         asl a
         rol $d8

         clc           ;fine var
         adc $07
         adc cox3,x
         bcc n3
         inc $d8
         clc
n3
         adc #24       ;fine-justage
         sta $d7
         bcc n4
         inc $d8
n4                     ;Y-CORD
         sec           ;deltablock
         lda coy1,x
         sbc $ab

         asl a         ;mal 2

         sec           ;sbc blk-char-zei
         sbc $a9

         clc           ;add coy2
         adc coy2,x

         asl a         ;mal 8
         asl a
         asl a

         clc           ;fine var
         adc $12
         adc coy3,x

         clc           ;fine-justage
         adc #22+8
         sta $d9

         txa           ;set spritcord
         asl a
         asl a
         tax
         ldy subsn,x
         lda $d9
         sta sy,y
         lda $d7
         sta slox,y
         lda $d8
         and #1
         sta shix,y
         rts
         .bend

stoco
         .block
         ldx $d9
         lda $d7
         bpl n30
         eor #$ff
         clc
         adc #1
n30      and #7
         ldy $d7
         bpl n31
         eor #$ff
         clc
         adc #1
n31      sta cox3,x
         lda $d7
         lsr a
         lsr a
         lsr a
         tay
         lda quot3a,y
         sta cox2,x
         lda quot3b,y
         sta cox1,x

         clc
         lda icox3
         adc cox3,x
         bpl n1
         dec cox2,x
         jmp n3
n1       cmp #8
         bcc n2
         inc cox2,x
n3       and #7
n2       sta cox3,x

         clc
         lda icox2
         adc cox2,x
n9       bpl n5
         dec cox1,x
         clc
         adc #3
         jmp n9
         jmp n6
n5       cmp #3
         bcc n6
         sbc #3
         jmp n9
n6       sta cox2,x

         clc
         lda icox1
         adc cox1,x
         sta cox1,x


         lda $d8
         bpl n20
         eor #$ff
         clc
         adc #1
n20      sta $da
         and #7
         sta coy3,x
         lda $da
         lsr a
         lsr a
         lsr a
         sta coy2,x
         lsr a
         sta coy1,x
         ldy $d8
         bpl n22
         eor #$ff
         clc
         adc #1
         sta coy1,x
         lda coy2,x
         eor #$ff
         clc
         adc #1
         sta coy2,x
         lda coy3,x
         eor #$ff
         clc
         adc #1
         sta coy3,x
n22
         clc
         lda icoy3
         adc coy3,x
         bpl n11
         dec coy2,x
         jmp n13
n11      cmp #8
         bcc n12
         inc coy2,x
n13      and #7
n12      sta coy3,x

         clc
         lda icoy2
         adc coy2,x
n18      bpl n15
         dec coy1,x
         clc
         adc #2
         jmp n18
n15      cmp #2
         bcc n16
         inc coy1,x
         sbc #2
         jmp n18
n16      sta coy2,x

         clc
         lda icoy1
         adc coy1,x
         sta coy1,x
         rts

quot3a   .byte 0,1,2,0,1,2,0,1,2
         .byte 0,1,2,0,1,2,0
         .byte 0,1,2,0,1,2,0,1,2
         .byte 0,1,2,0,1,2,0
quot3b   .byte 0,0,0,1,1,1,2,2,2
         .byte 3,3,3,4,4,4,5
         .byte $fb,$fb,$fb,$fc,$fc,$fc
         .byte $fd,$fd,$fd,$fe,$fe,$fe
         .byte $ff,$ff,$ff,$00
         .bend


unsharp  .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
subj     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
blockx   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
blocky   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
spanz    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
phast    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
aphast   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
wamtz    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
awlox    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
awy      .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
awlox2   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
awy2     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
awlox3   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
awy3     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
awphast  .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
wphast   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
aamlob   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
aamhib   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
oldwam   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
sumod    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0


scol3    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
sdz3     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0

sdelx    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
sdely    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0

konstl   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
kontab   .byte 1,2,2,2,3,3,3
         .byte 4,4,4,4,4,4
konxd    .byte 0,0,0
         .byte $18,0,0
         .byte $00,0,0
         .byte $00,0,0
         .byte $18,$30,0
         .byte $00,$00,0
         .byte $00,$00,0
         .byte $18,$30,$48
         .byte $00,$00,$00
         .byte $00,$18,$18
         .byte $18,$00,$00
         .byte $00,$00,$00
         .byte $00,$00,$00
konyd    .byte 0,0,0
         .byte $00,0,0
         .byte $eb,0,0
         .byte $00,0,0
         .byte $00,$00,0
         .byte $eb,$d6,0
         .byte $00,$00,0
         .byte $00,$00,$00
         .byte $eb,$d6,$c1
         .byte $eb,$00,$eb
         .byte $00,$00,$00
         .byte $eb,$00,$eb
         .byte $00,$00,$00


contx    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
conty    .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
collxd   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
collyd   .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
colbasy  .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
ctbasy   .byte 0,13,5,253,245,237

status   .byte 0
subfreq  .byte 0
ksuz     .byte 0

icox1    .byte 0
icox2    .byte 0
icox3    .byte 0
icoy1    .byte 0
icoy2    .byte 0
icoy3    .byte 0



cox1     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
cox2     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
cox3     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
coy1     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
coy2     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0
coy3     .byte 0,0,0,0,0,0,0,0,0,0
         .byte 0,0,0,0,0,0,0,0,0,0