!convtab pet
		setflop=$736e
		untalk=$73b7
		unlist=$73bc
		listen=$73c1
		position=$7104
		getin=$72cf
		block=$7181
		nextblock=$720e
		*= $8800
irqon		sei
		lda #$ff
		sta $0340
		sta $0343
		sta $0346
		sta $0349
		sta $034c
		sta $034f
		sta $0352
		sta $0355
		lda #<(irq)
		ldx #>(irq)
		sta $0314
		stx $0315
		lda #<(restore)
		ldx #>(restore)
		sta $0318
		stx $0319
		sta $fffa
		stx $fffb
		lda #01
		sta $d015
		sta $d01b
		lda #$0d
		sta $07f8
		cli
		rts
restore		jsr 64789
		jsr 64931
		jsr 58648
		lda #$37
		sta $01
		lda #12
		sta $d020
		sta $d021
		ldx #00
next2		lda azzil,x
		jsr $ffd2
		inx
		cpx #34
		bne next2
		lda #12
		sta $d3
		lda #32
		ldx $35
		stx $b0
		ldx $36
		stx $b1
		jsr prib0
		lda #$30
		sta $b0
		lda #0
		sta $b1
		iny
		jsr puthex
		dey
		jsr puthex
		jsr spc
		ldy #3
		jsr puthex
		dey
		jsr puthex
tascur		jsr return
tasc		jsr irqon
taste		jsr $ffe4
		beq taste
		cmp #13
		beq enter
bsout		jsr $ffd2
		jmp taste
enter		ldy #00
		ldx #00
		stx get+1
next1		lda ($d1),y
		cmp #32
		beq space
		bcs ident
		ora #$40
ident		sta $0200,x
		inx
space		iny
		cpy #39
		bne next1
		sta $0200,x
		jsr get
		sta 2
		ldx #00
next4		lda kommand,x
		cmp 2
		bne next3
		txa
		asl
		tax
		lda komgo,x
		sta go+1
		inx
		lda komgo,x
		sta go+2
		jsr irqoff
go		jmp 0000
next3		inx
		cpx #11
		bne next4
error		lda #63
		jsr $ffd2
		jsr irqon
		lda #13
		jmp bsout
getadress	jsr getbyt
		sta $b1
		jsr getbyt
		sta $b0
		rts
addxa		jsr getbyt
		sta 7
		jsr getbyt
		ldx 7
		rts
		jmp error
irq		lda #01
		sta $cc
		jsr zeilend
		bcs next138
noo		clc
		adc #3
		asl
		asl
		asl
		sta $d000
		rol $d010
		lda $d6
		asl
		asl
		asl
		clc
		adc #50
		sta $d001
		jmp $ea31
next138		sec
		sbc #40
		jmp noo
hexaus		pha
		and #$f0
		lsr
		lsr
		lsr
		lsr
		tax
		lda aschex,x
		jsr $ffd2
		pla
		and #$0f
		tax
		lda aschex,x
		jsr $ffd2
		rts
get		lda $0200
		inc get+1
		rts
getbyte		jsr getbyt
		rts
getbyt		jsr nibble
		asl
		asl
		asl
		asl
		sta 3
		jsr nibble
		ora 3
		rts
nibble		jsr get
		ldx #0
next5		cmp aschex,x
		beq foni
		inx
		cpx #16
		bne next5
		pla
		pla
		pla
		pla
		pla
		pla
		jmp error
foni		txa
		rts
memory		jsr rga
next11		jsr mzeile
		jsr adcb0
		jmp next11
list		jsr rga
next19		jsr diszeil
		jsr adcb0
		jmp next19
diszeil		lda #59
		jsr prib0
		jsr mget
		sta 4
		and #$0f
		tax
		lda bef1,x
		jsr $ffd2
		lda bef2,x
		jsr $ffd2
		lda bef3,x
		jsr $ffd2
		lda xy,x
		sta 5
		lda #44
		asl $4
		bcc next15
		lda #47
next15		jsr $ffd2
		lda #88
		ldx #89
		asl $4
		bcc next17
		txa
		dex
next17		dec $5
		bne no1
		lda #32
no1		jsr $ffd2
		stx $5
		jsr spc
		asl $4
		adc #03
		jsr $ffd2
		iny
		jsr lohimget
		asl $4
		bcc kkkk
		jsr spc
		lda $5
		jsr $ffd2
kkkk		ldy #0
		lda #25
		sta $d3
next18		jsr puthex
		jsr spc
		iny
		cpy #3
		bne next18
		rts
inpmemory	jsr getadress
		ldy #00
next21		jsr getbyte
next20		jsr mset
		iny
		cpy #8
		bne next21
		jsr clrzeile
		jsr mzeile
		jmp tascur
prib0		jsr $ffd2
		lda $b1
		jsr hexaus
		lda $b0
		jsr hexaus
		jsr spc
		ldy #0
		jmp $ffd2
addyb		tya
		clc
		adc $b0
		sta $b0
		lda $b1
		adc #00
		sta $b1
		rts
adcb0		jsr addyb
next12		lda $028d
		beq next13
		jsr return
		rts
next13		lda 203
		cmp #63
		bne next12
		pla
		pla
		jmp tascur
return		lda #13
		jmp $ffd2
irqoff		sei
		lda #$31
		sta $0314
		lda #$ea
		sta $0315
		lda #00
		sta $d015
		cli
		rts
mget		sei
		ldx #$30
		stx 1
		lda ($b0),y
nnnn		ldx #$37
		stx 1
		cli
		rts
spc		lda #32
		jmp $ffd2
lohimget	jsr puthex
		iny
		jsr puthex
		iny
		rts
puthex		jsr mget
		jmp hexaus
mset		sei
		ldx #$30
		stx 1
		sta ($b0),y
		jmp nnnn
clrzeile	lda #0
		sta $d3
		ldx $d6
		jmp $e9ff
rga		jsr return
		jmp getadress
mzeile		lda #58
		jsr prib0
next10		jsr lohimget
		jsr spc
		cpy #8
		bne next10
		rts
aget		ldy #0
		jsr mget
		asl
		sta 8
		iny
		jsr getadress
		ldx #3
next30		jsr get
		sta 4,x
		dex
		bne next30
		stx 4
next31		lda bef1,x
		cmp 7
		beq next32
nobef		inx
		cpx #16
		bne next31
		jmp error
next32		lda bef2,x
		cmp 6
		bne nobef
		lda bef3,x
		cmp 5
		bne nobef
		stx 5
		lda #44
		jsr verget
		jsr xory
		beq next34
		dec get+1
next34		rol $4
		lda #35
		jsr verget
		jsr addxa
		pha
		txa
		jsr mset
		pla
		iny
		jsr mset
		jsr xory
		bne next39
		php
		pla
		eor #01
		pha
		ror 4
		ror 4
		plp
		rol 4
		rol 4
		sec
next39		rol $4
		lda 4
		asl
		asl
		asl
		asl
		ora $5
		ldy #0
		jsr mset
		jsr clrzeile
		jsr diszeil
		jsr addyb
		jsr return
		lda #59
		jsr prib0
		jmp tasc
filpar		ldx #8
		jmp $ffba
filnam		jsr namsu
		bne no52
		ldx #0
next51		jsr namsu
		beq next54
		inx
		cpx #16
		bne next51
no52		pla
		pla
		jmp error
next54		ldy #2
		txa
		ldx #2
		jmp $ffbd
namsu		jsr get
		cmp #47
		rts
verget		sta 7
		jsr get
		cmp 7
		bne next40
		clc
		bcc next41
next40		sec
next41		rol $4
		rts
xory		jsr get
		cmp #88
		beq verx
		bcs very
		ldx #1
		rts
verx		clc
very		ldx #0
		rts
azzilen		jsr rga
		lda #59
		jsr prib0
		jmp tasc
save		jsr filpar
		jsr filnam
		jsr getadress
		jsr addxa
		stx 5
		ldy 5
		tax
		lda #$b0
		jsr $ffd8
		jmp tascur
load		jsr filnam
		ldy #01
		jsr namsu
		bne next50
		dey
		jsr getadress
next50		jsr filpar
		lda #00
		ldx $b0
		ldy $b1
		jsr $ffd5
		jmp tascur
catalog		jsr return
		lda #01
		ldy #$e9
		ldx #$e1
		jsr $ffbd
		lda #1
		ldx #8
		ldy #0
		jsr $ffba
		jsr $ffc0
		ldx #1
		jsr $ffc6
		ldy #5
next60		sty $fb
		jsr $ffcf
		tax
		ldy $fb
		dey
		bne next60
		jsr $ffcf
		ldy $90
		bne next61
		jsr $bdcd
		jsr spc
next64		jsr $ffcf
		sta $fb
		beq next63
		jsr $ffd2
		jmp next64
next63		jsr return
next65		lda $028d
		beq no99
		ldy #3
		jmp next60
no99		lda 203
		cmp #63
		bne next65
next61		jsr $ffcc
		lda #1
		jsr $ffc3
		jmp tasc
start		jsr rga
		lda $b0
		sta $35
		lda $b1
		sta $36
		ldx #00
next900		lda corddata,x
		sta $16,x
		inx
		cpx #08
		bne next900
next901		lda corddata,x
		sta $d000-8,x
		inx
		cpx #47+8
		bne next901
		lda #01
		sta $dc0d
		jsr $750b
		jsr setflop
		lda #$50
		sta $02ef
		lda #08
		sta $9f
		lda #04
		sta $3d
		sta $3f
		ldx #00
		lda #14
weitsoo		sta $dae9,x
		inx
		bne weitsoo
		sta $07f8
weitsoo2	lda $3d00,x
		sta $0380,x
		inx
		cpx #$80
		bne weitsoo2
		jmp $7000
savbytes	jsr lodblock
		jsr addxa
		sta hol+1
		stx hol+2
		jsr addxa
		tax
		ldy $7
		iny
		lda #<(hol)
		sta next203+1
		lda #>(hol)
		sta next203+2
		ldx #00
		lda #14
weiterso	sta $dae9,x
		inx
		bne weiterso
		lda #$0d
		sta $07f8
		jsr savblo
		jmp tascur
hol		lda $8888
		inc hol+1
		bne pudel
		inc hol+2
pudel		rts
corddata	!byte $b0,$20,$20,$30,$31,$18,$28,$38
		!byte 60,60,90,40,0,0,0,0,0,0,0,0,0,0,0,0,0
		!byte $1b,$b2,$0,$0,$ff,$d8,0,$1d,$79,$01,0,$fd,0,0,0,0,0,0,0,0,12
		!byte 01,0,8,11,11,11,11,11,11
lodtext		jsr lodblock
		lda $b0
		sta $8
		lda $b1
		sta $9
		jsr position
		lda #0
		sta $d6
		sta scre+1
		sta scre2+1
		ldx #04
		stx scre+2
		stx scre2+2
		stx 7
		ldy #$c0
next153		jsr getin
scre		sta $0400
		inc scre+1
		bne next154
		inc scre+2
next154		dey
		bne next153
		dec 7
		bne next153
		jsr untalk
		jsr return
		jsr irqon
next111		jsr $ffe4
		beq next111
		cmp #141
		beq next666
		cmp #13
		bne next113
next666		jsr zeilend
		bcs next622
		ldx #0
next633		lda #17
		bne next114
next622		ldx #40
		bne next633
next113		cmp #"…"
		beq ctrlsave
next112		jsr $ffd2
		lda $d6
		cmp #24
		bne next111
		lda #145
		ldx #0
next114		stx $d3
		jmp next112
ctrlsave	ldx #$c0
		ldy #$04
		lda #<(sprink)
		sta next203+1
		lda #>(sprink)
		sta next203+2
		lda $8
		sta $b0
		lda $9
		sta $b1
		jsr savblo
		jmp restore
savblock	inc $799c
		jsr block
		dec $799c
		rts
zeilend		lda $d3
		cmp #40
		rts
bef1		!pet "rctiasinlssrjsii"
bef2		!pet "otxndbsooauemekg"
bef3		!pet "oxtpddttdvbtptlr"
xy		!byte 1,1,0,1,0,0,0,0,0,0,1,1,1,0,0,0
komgo		!word memory,inpmemory,list,azzilen,save,load,catalog,start
		!word lodtext,savbytes,aget
azzil		!byte 142,144,147,18
		!pet "triceratops; pc    xr   yr   "
		!byte 13
kommand		!pet "m:daslcgtw"
		!byte 59
aschex		!pet "0123456789abcdef"
sprink		jmp tp200
tp200		ldx #00
scre2		lda $0400
		inc scre2+1
		bne nexttp1
		inc scre2+2
nexttp1		cmp #65
		bcs btp1
		cmp #32
		bcs btp2
btp3		sta $7a,x
		inx
		cpx #4
		bne scre2
		lda $7c
		asl $7d
		asl $7d
		asl $7d
		rol
		asl $7d
		rol
		asl $7d
		rol
		rol $7b
		asl $7d
		rol
		rol $7b
		asl $7d
		rol
		rol $7b
		rol $7a
		asl $7d
		rol
		rol $7b
		rol $7a
		eor #73
		sta $7c
		lda $7b
		eor #5
		sta $7b
		lda #<(tp201)
		sta sprink+1
		lda $7a
		eor #15
		rts
tp201		lda #<(tp202)
		sta sprink+1
		lda $7b
		rts
tp202		lda #<(tp200)
		sta sprink+1
		lda $7c
		rts
btp1		sec
		sbc #38
		bne btp3
btp2		ldy #53
next233		cmp exzei-53,y
		beq next234
		iny
		cpy #53+11
		bne next233
		dey
next234		tya
		bne btp3
exzei		!byte 33,34,44,46,58,40,41,63,59,32,39
listiii		jsr untalk
		jsr listen
		lda #$68
		jmp $ff93
lodblock	jsr getadress
		jmp setflop
savblo		stx $2c
		sty $2d
		jsr position
		jsr listiii
next203		jsr 0000
		jsr $ffa8
		inc $b0
		bne next202
		jsr savblock
		jsr nextblock
		jsr listiii
next202		dec $2c
		bne next203
		dec $2d
		bne next203
		jsr savblock
		jmp untalk